global: variable names are CamelCase

            ___  _         ___     __
           / _ )(_)__ _   / _/__ _/ /_
          / _  / / _ `/  / _/ _ `/ __/
         /____/_/\_, /  /_/ \_,_/\__/
 _       __     /___/       _             __
| |     / /___ __________  (_)___  ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / /  / / / / / / / / /_/ /_/
|__/|__/\__,_/_/  /_/ /_/_/_/ /_/\__, (_)
                                /____/

RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:

[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

That looks ok. Now we use a script:

{ :local interface "en1";
  / interface print where name=$interface; }

And the result...

[admin@MikroTik] > { :local interface "en1";
{...   / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

... still looks ok.
We make a little modification to the script:

{ :local name "en1";
  / interface print where name=$name; }

And the result:

[admin@MikroTik] > { :local name "en1";
{...   / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598
 1   S en2                                 ether            1500  1598
 2   S en3                                 ether            1500  1598
 3   S en4                                 ether            1500  1598
 4   S en5                                 ether            1500  1598
 5  R  br-local                            bridge           1500  1598

Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).

And another modification:

{ :local type "en1";
  / interface print where name=$type; }

And the result:

[admin@MikroTik] > { :local type "en1";
{...   / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU

Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.

The answer from MikroTik support (in Ticket#2019010222000454):

> This is how scripting works in RouterOS and we will not fix it.

To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...

*fingers crossed*

1 files changed, 18 insertions, 18 deletions

diff --git a/accesslist-duplicates.template b/accesslist-duplicates.template
index 3b6a22a..18225a6 100644
--- a/accesslist-duplicates.template
+++ b/accesslist-duplicates.template
@@ -7,31 +7,31 @@
 # !! This is just a template! Replace '%PATH%' with 'caps-man'
 # !! or 'interface wireless'!
 
-:local seen [ :toarray "" ];
-:local shown [ :toarray "" ];
-
 :global Read;
 
-:foreach acclist in=[ / %PATH% access-list find where mac-address!="00:00:00:00:00:00" ] do={
-  :local mac [ / %PATH% access-list get $acclist mac-address ];
-  :foreach "seen-mac" in=$seen do={
-    :if ($"seen-mac" = $mac) do={
-      :local skip 0;
-      :foreach "shown-mac" in=$shown do={
-        :if ($"shown-mac" = $mac) do={ :set skip 1; }
+:local Seen [ :toarray "" ];
+:local Shown [ :toarray "" ];
+
+:foreach AccList in=[ / %PATH% access-list find where mac-address!="00:00:00:00:00:00" ] do={
+  :local Mac [ / %PATH% access-list get $AccList mac-address ];
+  :foreach SeenMac in=$Seen do={
+    :if ($SeenMac = $Mac) do={
+      :local Skip 0;
+      :foreach ShownMac in=$Shown do={
+        :if ($ShownMac = $Mac) do={ :set Skip 1; }
       }
-      :if ($skip = 0) do={
-        / %PATH% access-list print where mac-address=$mac;
-        :set shown ( $shown , $mac );
+      :if ($Skip = 0) do={
+        / %PATH% access-list print where mac-address=$Mac;
+        :set Shown ($Shown, $Mac);
 
         :put "\nEnter to skip, numeric id to remove!";
-        :local remove [ $Read ];
-        :if ($remove != "") do={
-          :put ("Removing numeric id " . $remove . "...\n");
-          / %PATH% access-list remove $remove;
+        :local Remove [ $Read ];
+        :if ($Remove != "") do={
+          :put ("Removing numeric id " . $Remove . "...\n");
+          / %PATH% access-list remove $Remove;
         }
       }
     }
   }
-  :set seen ( $seen , $mac );
+  :set Seen ($Seen, $Mac);
 }