global: variable names are CamelCase

            ___  _         ___     __
           / _ )(_)__ _   / _/__ _/ /_
          / _  / / _ `/  / _/ _ `/ __/
         /____/_/\_, /  /_/ \_,_/\__/
 _       __     /___/       _             __
| |     / /___ __________  (_)___  ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / /  / / / / / / / / /_/ /_/
|__/|__/\__,_/_/  /_/ /_/_/_/ /_/\__, (_)
                                /____/

RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:

[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

That looks ok. Now we use a script:

{ :local interface "en1";
  / interface print where name=$interface; }

And the result...

[admin@MikroTik] > { :local interface "en1";
{...   / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

... still looks ok.
We make a little modification to the script:

{ :local name "en1";
  / interface print where name=$name; }

And the result:

[admin@MikroTik] > { :local name "en1";
{...   / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598
 1   S en2                                 ether            1500  1598
 2   S en3                                 ether            1500  1598
 3   S en4                                 ether            1500  1598
 4   S en5                                 ether            1500  1598
 5  R  br-local                            bridge           1500  1598

Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).

And another modification:

{ :local type "en1";
  / interface print where name=$type; }

And the result:

[admin@MikroTik] > { :local type "en1";
{...   / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU

Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.

The answer from MikroTik support (in Ticket#2019010222000454):

> This is how scripting works in RouterOS and we will not fix it.

To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...

*fingers crossed*

1 files changed, 18 insertions, 18 deletions

diff --git a/capsman-download-packages b/capsman-download-packages
index 08e9535..babea59 100644
--- a/capsman-download-packages
+++ b/capsman-download-packages
@@ -9,29 +9,29 @@
 
 :global DownloadPackage;
 
-:local "package-path" [ / caps-man manager get package-path ];
-:if ([ :pick $"package-path" 0 ] = "/") do={
-  :set "package-path" [ :pick $"package-path" 1 [ :len $"package-path" ] ];
+:local PackagePath [ / caps-man manager get package-path ];
+:if ([ :pick $PackagePath 0 ] = "/") do={
+  :set PackagePath [ :pick $PackagePath 1 [ :len $PackagePath ] ];
 }
-:local "installed-version" [ / system package update get installed-version ];
-:local updated false;
+:local InstalledVersion [ / system package update get installed-version ];
+:local Updated false;
 
-:foreach package in=[ / file find where type=package \
-      package-version!=$"installed-version" name~("^" . $"package-path") ] do={
-  :local "package-name" [ / file get $package package-name ];
-  :local "package-architecture" [ / file get $package package-architecture ];
-  :if ($"package-architecture" = "mips") do={
-    :set "package-architecture" "mipsbe";
+:foreach Package in=[ / file find where type=package \
+      package-version!=$InstalledVersion name~("^" . $PackagePath) ] do={
+  :local PackageName [ / file get $Package package-name ];
+  :local PackageArchitecture [ / file get $Package package-architecture ];
+  :if ($PackageArchitecture = "mips") do={
+    :set PackageArchitecture "mipsbe";
   }
-  :if ($"package-name" = "wireless@") do={
-    :set "package-name" "wireless";
+  :if ($PackageName = "wireless@") do={
+    :set PackageName "wireless";
   }
-  :if ([ $DownloadPackage $"package-name" $"installed-version" $"package-architecture" $"package-path" ] = true) do={
-    :set updated true;
-    / file remove $package;
+  :if ([ $DownloadPackage $PackageName $InstalledVersion $PackageArchitecture $PackagePath ] = true) do={
+    :set Updated true;
+    / file remove $Package;
   }
 }
 
-:if ($updated = true) do={
-  / caps-man remote-cap upgrade [ find where version!=$"installed-version" ];
+:if ($Updated = true) do={
+  / caps-man remote-cap upgrade [ find where version!=$InstalledVersion ];
 }