global: variable names are CamelCase

            ___  _         ___     __
           / _ )(_)__ _   / _/__ _/ /_
          / _  / / _ `/  / _/ _ `/ __/
         /____/_/\_, /  /_/ \_,_/\__/
 _       __     /___/       _             __
| |     / /___ __________  (_)___  ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / /  / / / / / / / / /_/ /_/
|__/|__/\__,_/_/  /_/ /_/_/_/ /_/\__, (_)
                                /____/

RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:

[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

That looks ok. Now we use a script:

{ :local interface "en1";
  / interface print where name=$interface; }

And the result...

[admin@MikroTik] > { :local interface "en1";
{...   / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

... still looks ok.
We make a little modification to the script:

{ :local name "en1";
  / interface print where name=$name; }

And the result:

[admin@MikroTik] > { :local name "en1";
{...   / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598
 1   S en2                                 ether            1500  1598
 2   S en3                                 ether            1500  1598
 3   S en4                                 ether            1500  1598
 4   S en5                                 ether            1500  1598
 5  R  br-local                            bridge           1500  1598

Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).

And another modification:

{ :local type "en1";
  / interface print where name=$type; }

And the result:

[admin@MikroTik] > { :local type "en1";
{...   / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU

Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.

The answer from MikroTik support (in Ticket#2019010222000454):

> This is how scripting works in RouterOS and we will not fix it.

To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...

*fingers crossed*

1 files changed, 38 insertions, 38 deletions

diff --git a/collect-wireless-mac.capsman b/collect-wireless-mac.capsman
index 08c0bdb..cca29e8 100644
--- a/collect-wireless-mac.capsman
+++ b/collect-wireless-mac.capsman
@@ -6,54 +6,54 @@
 #
 # !! Do not edit this file, it is generated from template!
 
-:global "identity";
+:global Identity;
 
 :global GetMacVendor;
 :global SendNotification;
 
-:local "place-before" [ / caps-man access-list find where comment="--- collected above ---" disabled ];
-:if ([ :len $"place-before" ] = 0) do={
+:local PlaceBefore [ / caps-man access-list find where comment="--- collected above ---" disabled ];
+:if ([ :len $PlaceBefore ] = 0) do={
   :error "Missing disabled access-list entry with comment '--- collected above ---'";
 }
 
-:foreach regtbl in=[ / caps-man registration-table find ] do={
-  :local mac [ / caps-man registration-table get $regtbl mac-address ];
-  :local acclst [ :pick [ / caps-man access-list find where mac-address=$mac ] 0 ];
-  :if ( [ :len $acclst ] = 0 ) do={
-    :local hostname "no dhcp lease";
-    :local address "no dhcp lease";
-    :local lease [ / ip dhcp-server lease find where mac-address=$mac ];
-    :if ( [ :len $lease ] > 0 ) do={
-      :set hostname [ / ip dhcp-server lease get $lease host-name ];
-      :set address [ / ip dhcp-server lease get $lease address ];
+:foreach RegTbl in=[ / caps-man registration-table find ] do={
+  :local Mac [ / caps-man registration-table get $RegTbl mac-address ];
+  :local AccessList [ :pick [ / caps-man access-list find where mac-address=$Mac ] 0 ];
+  :if ([ :len $AccessList ] = 0) do={
+    :local HostName "no dhcp lease";
+    :local Address "no dhcp lease";
+    :local Lease [ / ip dhcp-server lease find where mac-address=$Mac ];
+    :if ([ :len $Lease ] > 0) do={
+      :set HostName [ / ip dhcp-server lease get $Lease host-name ];
+      :set Address [ / ip dhcp-server lease get $Lease address ];
     }
-    :if ( [ :len $hostname ] = 0 ) do={
-      :set hostname "no hostname";
+    :if ([ :len $HostName ] = 0) do={
+      :set HostName "no hostname";
     }
-    :if ( [ :len $address ] = 0 ) do={
-      :set address "no address";
+    :if ([ :len $Address ] = 0) do={
+      :set Address "no address";
     }
-    :local regentry [ / caps-man registration-table find where mac-address=$mac ];
-    :local interface [ / caps-man registration-table get $regentry interface ];
-    :local ssid [ / caps-man registration-table get $regentry ssid ];
-    :local datetime ([ / system clock get date ] . " " . [ / system clock get time ]);
-    :local vendor [ $GetMacVendor $mac ];
-    :local message ("unknown MAC address " . $mac . " (" . $vendor . ", " . $hostname . ") " . \
-      "first seen on " . $datetime . " connected to SSID " . $ssid . ", interface " . $interface);
-    / log info $message;
-    / caps-man access-list add place-before=$"place-before" comment=$message mac-address=$mac disabled=yes;
-    $SendNotification ($mac . " connected to " . $ssid) \
-      ("A device with unknown MAC address connected to " . $ssid . " on " . $identity . ".\n\n" . \
-        "Controller: " . $identity . "\n" . \
-        "Interface:  " . $interface . "\n" . \
-        "SSID:       " . $ssid . "\n" . \
-        "MAC:        " . $mac . "\n" . \
-        "Vendor:     " . $vendor . "\n" . \
-        "Hostname:   " . $hostname . "\n" . \
-        "Address:    " . $address . "\n" . \
-        "Date:       " . $datetime);
+    :local RegEntry [ / caps-man registration-table find where mac-address=$Mac ];
+    :local Interface [ / caps-man registration-table get $RegEntry interface ];
+    :local Ssid [ / caps-man registration-table get $RegEntry ssid ];
+    :local DateTime ([ / system clock get date ] . " " . [ / system clock get time ]);
+    :local Vendor [ $GetMacVendor $Mac ];
+    :local Message ("unknown MAC address " . $Mac . " (" . $Vendor . ", " . $HostName . ") " . \
+      "first seen on " . $DateTime . " connected to SSID " . $Ssid . ", interface " . $Interface);
+    / log info $Message;
+    / caps-man access-list add place-before=$PlaceBefore comment=$Message mac-address=$Mac disabled=yes;
+    $SendNotification ($Mac . " connected to " . $Ssid) \
+      ("A device with unknown MAC address connected to " . $Ssid . " on " . $Identity . ".\n\n" . \
+        "Controller: " . $Identity . "\n" . \
+        "Interface:  " . $Interface . "\n" . \
+        "SSID:       " . $Ssid . "\n" . \
+        "MAC:        " . $Mac . "\n" . \
+        "Vendor:     " . $Vendor . "\n" . \
+        "Hostname:   " . $HostName . "\n" . \
+        "Address:    " . $Address . "\n" . \
+        "Date:       " . $DateTime);
   } else={
-    :local comment [ / caps-man access-list get $acclst comment ];
-    :log debug ("MAC address " . $mac . " already known: " . $comment);
+    :local Comment [ / caps-man access-list get $AccessList comment ];
+    :log debug ("MAC address " . $Mac . " already known: " . $Comment);
   }
 }