global: variable names are CamelCase

            ___  _         ___     __
           / _ )(_)__ _   / _/__ _/ /_
          / _  / / _ `/  / _/ _ `/ __/
         /____/_/\_, /  /_/ \_,_/\__/
 _       __     /___/       _             __
| |     / /___ __________  (_)___  ____ _/ /
| | /| / / __ `/ ___/ __ \/ / __ \/ __ `/ /
| |/ |/ / /_/ / /  / / / / / / / / /_/ /_/
|__/|__/\__,_/_/  /_/ /_/_/_/ /_/\__, (_)
                                /____/

RouterOS has some odd behavior when it comes to variable names. Let's
have a look at the interfaces:

[admin@MikroTik] > / interface print where name=en1
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

That looks ok. Now we use a script:

{ :local interface "en1";
  / interface print where name=$interface; }

And the result...

[admin@MikroTik] > { :local interface "en1";
{...   / interface print where name=$interface; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598

... still looks ok.
We make a little modification to the script:

{ :local name "en1";
  / interface print where name=$name; }

And the result:

[admin@MikroTik] > { :local name "en1";
{...   / interface print where name=$name; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU
 0  RS en1                                 ether            1500  1598
 1   S en2                                 ether            1500  1598
 2   S en3                                 ether            1500  1598
 3   S en4                                 ether            1500  1598
 4   S en5                                 ether            1500  1598
 5  R  br-local                            bridge           1500  1598

Ups! The filter has no effect!
That happens whenever the variable name ($name) matches the property
name (name=).

And another modification:

{ :local type "en1";
  / interface print where name=$type; }

And the result:

[admin@MikroTik] > { :local type "en1";
{...   / interface print where name=$type; }
Flags: D - dynamic, X - disabled, R - running, S - slave
 #     NAME                                TYPE       ACTUAL-MTU L2MTU

Ups! Nothing?
Even if the variable name ($type) matches whatever property name (type=)
things go wrong.

The answer from MikroTik support (in Ticket#2019010222000454):

> This is how scripting works in RouterOS and we will not fix it.

To get around this we use variable names in CamelCase. Let's hope
Mikrotik never ever introduces property names in CamelCase...

*fingers crossed*

1 files changed, 19 insertions, 17 deletions

diff --git a/ipv6-update b/ipv6-update
index 12b9856..73336c1 100644
--- a/ipv6-update
+++ b/ipv6-update
@@ -4,31 +4,33 @@
 #
 # update firewall and dns settings on IPv6 prefix change
 
-:local pool [ / ipv6 pool get [ find where prefix=$"pd-prefix" ] name ];
-:local addrlist [ / ipv6 firewall address-list find where comment=("ipv6-pool-" . $pool) ];
-:local oldprefix [ / ipv6 firewall address-list get $addrlist address ];
+:local PdPrefix $"pd-prefix";
+
+:local Pool [ / ipv6 pool get [ find where prefix=$PdPrefix ] name ];
+:local AddrList [ / ipv6 firewall address-list find where comment=("ipv6-pool-" . $Pool) ];
+:local OldPrefix [ / ipv6 firewall address-list get $AddrList address ];
 
 # give the interfaces a moment to receive their addresses
 :delay 2s;
 
-if ($oldprefix != $"pd-prefix") do={
-  :log info ("Updating IPv6 address list with new IPv6 prefix " . $"pd-prefix");
-  / ipv6 firewall address-list set address=$"pd-prefix" $addrlist;
+if ($OldPrefix != $PdPrefix) do={
+  :log info ("Updating IPv6 address list with new IPv6 prefix " . $PdPrefix);
+  / ipv6 firewall address-list set address=$PdPrefix $AddrList;
 
-  :foreach record in=[ / ip dns static find where comment~("ipv6-pool-" . $pool) ] do={
-    :local comment [ :toarray [ / ip dns static get $record comment ] ];
-    :local intname [ :pick [ :pick $comment 1 ] 10 99 ];
-    :local suffix [ :pick [ :pick $comment 2 ] 7 99 ];
+  :foreach Record in=[ / ip dns static find where comment~("ipv6-pool-" . $Pool) ] do={
+    :local Comment [ :toarray [ / ip dns static get $Record comment ] ];
+    :local IntName [ :pick [ :pick $Comment 1 ] 10 99 ];
+    :local Suffix [ :pick [ :pick $Comment 2 ] 7 99 ];
 
-    :local prefix [ / ipv6 address get [ find where interface=$intname from-pool=$pool global ] address ];
-    :local prefix64 [ :pick $prefix 0 [ :find $prefix "::/64" ] ];
+    :local Prefix [ / ipv6 address get [ find where interface=$IntName from-pool=$Pool global ] address ];
+    :local Prefix64 [ :pick $Prefix 0 [ :find $Prefix "::/64" ] ];
 
-    :local name [ / ip dns static get $record name ];
-    :if ([ :len $name ] = 0) do={
-      :set name [ / ip dns static get $record regex ];
+    :local Name [ / ip dns static get $Record name ];
+    :if ([ :len $Name ] = 0) do={
+      :set Name [ / ip dns static get $Record regex ];
     }
 
-    :log info ("Updating DNS record for " . $name . " to " . $prefix64 . ":" . $suffix);
-    / ip dns static set address=($prefix64 . ":" . $suffix) $record;
+    :log info ("Updating DNS record for " . $Name . " to " . $Prefix64 . ":" . $Suffix);
+    / ip dns static set address=($Prefix64 . ":" . $Suffix) $Record;
   }
 }